Изображения

Фоны

Часто можно услышать термин БГ (BG) (англ. BackGround - фон).

Общий синтаксис для вывода фона: scene <Название фона> или show <Название фона>

Разница между scene и show

В первом случае команда очищает все слои и показывает изображение, во втором — просто показывает изображение поверх других. Приведём пример:

label my_mod:
    show bg ext_square_day # Площадь
    show dv smile pioneer2 at left # Слева появляется Алиса
    show mi happy pioneer at center # Мику посередине
    show un smile pioneer at left # А Лена левее
    with dissolve # Пишем в конце всех строчек, а не у каждой, чтобы и БГ, и спрайты появились сразу, а не поочерёдно.
    "Некие действия"
    scene bg ext_square_day with dissolve
    "Показываем площадь, но теперь все спрайты убрались совсем."
    "Если уберём фон с помощью `hide`, то позади него ничего не будет."

Это был пример с использованием scene для показа изображения. Фона, в нашем случае.

label my_mod_2:
    show bg ext_square_day # Площадь
    show dv smile pioneer2 at left # Слева появляется Алиса
    show mi happy pioneer at center # Мику посередине
    show un smile pioneer at left # А Лена левее
    with dissolve # Пишем в конце всех строчек, а не у каждой, чтобы и БГ, и спрайты появились сразу, а не поочерёдно.
    "Некие действия"
    show bg ext_square_night with dissolve
    "Показываем ночную площадь."
    "Спрайты никуда не исчезают, остаются поверх фона, который меняется с дневного на ночной."

А здесь была использована команда show, которая лишь сменила фон на другой, не затрагивая другие изображения. Почему в нашем случае она сменила только фон, а не показала изображение поверх всех, смотрите ниже.

ПОДСКАЗКА

В данном случае, из-за того, что у фона имеется отступ после слова bg, слово bg сработало как "тэг" и сменился только фон, а не показался новый фон, который перекроет собой спрайты (А если бы изображение было без тэга и показалось поверх всего, то если бы мы его убрали при помощи hide, мы бы снова увидели нашу дневную площадь и спрайты девушек). Более подробно об этом рассказано чуть ниже.

Например:

scene bg bus_stop # Покажет нам автобусную остановку из времени Семёна
scene bg int_bus # Внутри автобуса, привезшего нас в "Совёнок"
scene bg ext_bus_night # Снаружи этого же автобуса, но уже ночью

Фоны из игры представлены в таблице: Фоны (BG)

Иллюстрации [CG]

Сам по себе термин "иллюстрации" редко применяется в данном контексте. В 99% случаев вы будете слышать CG (ЦГ) - Computer Graphics. Обычно это арт, который используется для демонстрации того, что нельзя показать при помощи фона и спрайтов.

Общий синтаксис для вывода иллюстраций: scene <Название арта> или show <Название арта>

Например:

scene cg d3_dv_scene_1 # Покажет арт с Алисой и Семёном на сцене, ночью.
scene cg d3_ussr_catched # Покажет лежащую на траве Ульянку.
scene cg d1_sl_dinner_0 # Славя и Семён ночью в столовой.

Все иллюстрации из игры представлены в таблице: Арты (CG)

Спрайты

Вызывается спрайт с помощью: show <Имя спрайта>

Обычно спрайты состоят из слов, разделённых пробелом: <имя персонажа> <эмоция> <одежда>

ПОДСКАЗКА

В оригинальной игре имя персонажа совпадает с ID говорящего из предыдущего раздела этого руководства.

Например:

show dv angry pioneer # Злая Алиса
show un cry sport # Плачущая Лена в спортивной форме

ВНИМАНИЕ

Если персонаж уже на экране, то повторное использование show будет менять эмоцию и/или одежду, если при повторном использовании у персонажа имеется "тэг". Скажем, в команде show un cry sport — un выступает в качестве "тэга" персонажа, поэтому при смене одежды/эмоции не нужно будет убирать предыдущую картинку. Точно так же тэги работают и с изображениями вроде БГ, ЦГ и прочих.

Для того чтобы убрать персонажа, воспользуйтесь: hide <Имя персонажа>

ПОДСКАЗКА

Если вы хотите вслед за этим сменить декорации, то прописывать hide для каждого персонажа необязательно. Команда scene сама их уберёт.

Все спрайты из игры представлены в таблице по ссылке: Спрайты